// ----------------------------------------------------------------------------
// KingTomato Ski
// Cause i'm so damn elite
// --
// Uses the spacebar as a default for jump, but you can change it. If you do
// wish to change it, go down to the bind part of this file.
//
// Installation:
//
// If you have the KingTomato pack, just place it in your KingTomato directory.
// If you do not have my pack, then simply place this file in to your
// \tribes\config directory. Next (if present) add the following line to
// the _bottom_ of the autoexec.cs file in the same directory:
//
//	Include("KT_Ski.cs");
//
// If you don't have autoexec.cs, just rename this file to that.
// ----------------------------------------------------------------------------

// ----------------------------------------------------------------------------
// Settings
$King::PB::DelaySki	= "0.05";	// Delay between jumps

// Don't touch this
$King::PB::["Ski"]	= false;

// ----------------------------------------------------------------------------
// Bind

// If you want to change the key for jump, follow the following steps:
//
// 1.	Open \tribes\config\config.cs
// 2.	Locate the line with the following text:
//		IDACTION_MOVEUP
// 3.	On that line, copy everything after the "MAKE," up until the "TO,"
// 4.	Paste the information in the same spot on both of the below lines
//	(After the MAKE, and BREAK, -- before the TO,)
// 5.	Save and load the file!

EditActionMap("playMap.sae");
bindCommand(keyboard0,	make,	"space",TO, "King::PB::Start(Ski);");
bindCommand(keyboard0,	break,	"space",TO, "King::PB::Stop(Ski);");

// ----------------------------------------------------------------------------
// Ski

function King::PB::Ski()
{
	if ($King::PB::["Ski"])
	{
		postAction(2048, IDACTION_MOVEUP, 1.0);

		// Make it easier to switch between client and fly mode in observer
		if (Client::GetTeam(getManagerId()) == -1)
			$King::PB::["Ski"] = false;

		schedule("King::PB::Ski();", $King::PB::DelaySki);
	}
}

// ----------------------------------------------------------------------------
// Toggles

function King::PB::Start(%what)
{
	if (!$King::PB::[%what])
	{
		$King::PB::[%what] = true;
		eval("King::PB::" @ %what @ "();");
	}
}

function King::PB::Stop(%what)
{
	$King::PB::[%what] = false;
}